看起来libxslt不支持XSLT 2.0和xsl：result-document.有没有办法使用libxslt或xsltproc来模仿xsl：result-document？
是的,有,使用
exsl:document.一个简单的例子：
==== foo.xsl ====
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="html"/>
<xsl:template match="/">
<exsl:document href="toc.html" method="html">
<html>
<body>
<xsl:apply-templates select=".//h1"/>
</body>
</html>
</exsl:document>
<xsl:apply-templates/>
</xsl:template>
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
以此为输入：
==== foo.html ====
<html>
<body>
<h1>Hello,world!</h1>
<p>Some longwinded text follows.</p>
</body>
</html>
当像这样运行时：
xsltproc foo.xsl foo.html
将这个产生给stdout：
<html>
<body>
<h1>Hello,world!</h1>
<p>Some longwinded text follows.</p>
</body>
</html>
同时也将此写入toc.html：
<html><body><h1>Hello,world!</h1></body></html>
版权声明：本文内容由互联网用户自发贡献，该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容， 请发送邮件至 dio@foxmail.com 举报，一经查实，本站将立刻删除。