将范围从已关闭的工作簿复制到特定的工作表

如何解决将范围从已关闭的工作簿复制到特定的工作表

我目前正在使用VBA脚本来自动化Excel工作表。目标是让代码使用称为“工作表”的工作表上的单元格A2中的文件路径打开文件（文件路径是动态的，是使用工作表中的信息形成的），并从文件中复制范围为A1：E200的数据并将数据粘贴到从A1开始的名为HOURS的工作表上的原始工作簿中。目前，我已经打开文件，但是尝试复制信息时出现“不匹配”错误。在下面，我附上了使用的代码。我希望有人能够帮助您理解错误！关闭部分也有同样的问题。注意：我是VBA的新秀，所以请尽可能清楚

Sub Button1_Click()
Call Test
Call Copy_Method
Call CloseWorkbook

End Sub
Sub Test()
    Dim strFName As String
    
    strFName = Sheet4.Range("A2").Value
    Workbooks.Open Filename:=strFName
    
End Sub




Sub Copy_Method()
'Copy range to another workbook using Range.Copy Method

    Dim wb1 As Workbook
    Dim wb2 As Workbook
    Dim ws1 As Worksheet
    Dim ws2 As Worksheet
    
    Set wb2 = ThisWorkbook
    Set ws2 = wb2.Sheets("HOURS")
    Set wb1 = ThisWorkbook.Worksheets("Reports").Range("A2")
    Set ws1 = wb1.Sheets("Sheet")
    
    ws2.Range("A1:E200") = ws1.Range("A1:E200").Value
    
    
  
 
End Sub

Sub CloseWorkbook()

  Workbooks("venues_theeway_hours_August2020.XLS").Close SaveChanges:=True
  
  
  
End Sub

解决方法

您尝试过吗？

ws2.Range("A1:E200").Value = ws1.Range("A1:E200").Value

,

在这里，您自己的生活变得非常艰难，将代码分为3个子代码。更好

1. 重命名引用，使它们更易于区分源/目的地。
2. 将它们保持在一起，以便在创建工作簿/工作表时仍然可以对其进行引用：

---

很抱歉，如果我没有正确理解您的要求，我的代码将执行以下操作：

• 读取原始工作簿，工作表“ Reports”，文件名的范围A2。

• 打开该文件名作为“源”工作簿

• 从...复制数据。

• 该“源”工作簿，表格“ Sheet”，范围A1：E200

• ..至原始工作簿，“ HOURS”工作表，范围A1：E200

• ，然后关闭未保存的“源”工作簿，因为您没有进行任何更改。

---

Dim wbSource As Workbook
Dim wbDest As Workbook
Dim wsSource As Worksheet
Dim wsDest As Worksheet
Dim strFName As String

Set wbDest = ThisWorkbook
Set wsDest = wbDest.Sheets("HOURS")

strFName = wbDest.Worksheets("Reports").Range("A2").Value

Set wbSource = Workbooks.Open(strFName)
Set wsSource = wbSource.Worksheets("Sheet")

wsDest.Range("A1:E200").Value = wsSource.Range("A1:E200").Value

wbSource.Close SaveChanges:=False

我对您保存后的工作簿感到有些困惑？也许您实际上想关闭源工作表未保存并保存要向其中添加数据的目标工作表？在这种情况下，您需要将此行添加到上述代码的末尾。

wbDest.Close SaveChanges:=True