如何解决通过JSON动态创建节点和关系
在类似以下示例的结构中,我有数百个JSON:
{
"JsonExport": [
{
"entities": [
{
"identity": "ENTITY_001","surname": "SMIT","entityLocationRelation": [
{
"parentIdentification": "PARENT_ENTITY_001","typeRelation": "SEEN_AT","locationIdentity": "LOCATION_001"
},{
"parentIdentification": "PARENT_ENTITY_001","locationIdentity": "LOCATION_002"
}
],"entityEntityRelation": [
{
"parentIdentification": "PARENT_ENTITY_001","typeRelation": "FRIENDS_WITH","childIdentification": "ENTITY_002"
}
]
},{
"identity": "ENTITY_002","surname": "JACKSON","entityLocationRelation": [
{
"parentIdentification": "PARENT_ENTITY_002","locationIdentity": "LOCATION_001"
}
]
},{
"identity": "ENTITY_003","surname": "JOHNSON"
}
],"identification": "REGISTRATION_001","locations": [
{
"city": "LONDON","identity": "LOCATION_001"
},{
"city": "PARIS","identity": "LOCATION_002"
}
]
}
]
}
使用这些JSON,我想制作一个包含以下节点的图形:注册,实体和位置。我已经弄清楚了这部分,并做了以下内容:
WITH "file:///example.json" AS json_file
CALL apoc.load.json(json_file,"$.JsonExport.*" ) YIELD value AS data
MERGE(r:Registration {id:data.identification})
WITH json_file
CALL apoc.load.json(json_file,"$.JsonExport..locations.*" ) YIELD value AS locations
MERGE(l:Locations{identity:locations.identity,name:locations.city})
WITH json_file
CALL apoc.load.json(json_file,"$.JsonExport..entities.*" ) YIELD value AS entities
MERGE(e:Entities {name:entities.surname,identity:entities.identity})
所有实体和位置都应与注册有关。我以为可以通过使用以下代码来做到这一点:
MERGE (e)-[:REGISTERED_ON]->(r)
MERGE (l)-[:REGISTERED_ON]->(r)
但是此代码未提供所需的输出。它创建额外的“空”节点,并且不连接到注册节点。因此,第一个问题是:如何将位置和实体节点连接到注册节点。并且鉴于其他JSON,实体和位置应仅链接到特定注册。
此外,我想创建实体->位置关系和实体-实体关系,并使用给定类型的关系(SEEN_AT或FRIENDS_WITH)作为给定关系的标签。如何才能做到这一点?在这一点上,我有点迷茫,看不到如何解决。如果有人可以引导我朝正确的方向发展,我将很有义务。
解决方法
-
变量名称(如
e
和r
)未存储在数据库中,仅在单个查询中绑定到值。在具有未绑定变量的模式上MERGE
只会创建整个模式(包括为未绑定节点变量创建一个空节点)。 -
MERGE节点时,应只为该节点指定唯一标识属性,以避免重复。创建时要设置的其他任何属性都应使用
ON CREATE SET
设置。 -
将JSON数据解析3次以获取数据的不同区域效率不高。而且它的查询方式特别低效,因为每个后续的
CALL/MERGE
子句组都会执行多次(因为每个先前的CALL
都会产生多行,并且行数会成倍增加) 。您可以使用aggregation来解决这个问题,但是在您的情况下这是不必要的,因为您只需一次通过JSON数据即可完成整个查询。
这可能对您有用:
CALL apoc.load.json(json_file,"$.JsonExport.*" ) YIELD value AS data
MERGE(r:Registration {id:data.identification})
FOREACH(ent IN data.entities |
MERGE (e:Entities {identity: ent.identity})
ON CREATE SET e.name = ent.surname
MERGE (e)-[:REGISTERED_ON]->(r)
FOREACH(loc1 IN ent.entityLocationRelation |
MERGE (l1:Locations {identity: loc1.locationIdentity})
MERGE (e)-[:SEEN_AT]->(l1))
FOREACH(ent2 IN ent.entityEntityRelation |
MERGE (e2:Entities {identity: ent2.childIdentification})
MERGE (e)-[:FRIENDS_WITH]->(e2))
)
FOREACH(loc IN data.locations |
MERGE (l:Locations{identity:loc.identity})
ON CREATE SET l.name = loc.city
MERGE (l)-[:REGISTERED_ON]->(r)
)
为简单起见,它对FRIENDS_WITH
和REGISTERED_ON
关系类型进行硬编码,因为MERGE
仅支持硬编码的关系类型。
因此,在玩neo4j / cyper时,我学到了一些新知识,并找到了解决该问题的另一种方法。根据给定的示例数据,以下代码可以动态创建节点和边。
whenever sqlerror exit failure
版权声明:本文内容由互联网用户自发贡献,该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务,不拥有所有权,不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容, 请发送邮件至 dio@foxmail.com 举报,一经查实,本站将立刻删除。