具有两个以上列表的Terraset setproduct函数

如何解决具有两个以上列表的Terraset setproduct函数

在以下情况下，如何将Terraform setproduct函数与两个以上的列表一起使用，或者是否有其他方法可以达到最终结果。

在main.tf文件中，我有以下数据。

$ cat main.tf
variable "nodes" {
  default = ["1","2","3"]
}

variable "ebs_volumes" {
  default = [
    {
      ebs_name = "/dev/xdba"
      ebs_size = "50"
      ebs_type = "gp2"
    },{
      ebs_name = "/dev/xdbb"
      ebs_size = "20"
      ebs_type = "gp2"
    }
  ]
}

locals {
  ebs_name = [for i in var.ebs_volumes : i.ebs_name]
  ebs_size = [for i in var.ebs_volumes : i.ebs_size]
  ebs_type = [for i in var.ebs_volumes : i.ebs_type]
}

locals {
  node_disks = { for pair in setproduct(var.nodes,local.ebs_name) : "${pair[0]}:${pair[1]}" => {
    node_index = pair[0]
    ebs_name   = pair[1]
    ebs_size   = [for i in var.ebs_volumes : i.ebs_size]
    ebs_type   = [for i in var.ebs_volumes : i.ebs_type]
  } }
}

output "combined" {
  value = local.node_disks
}

当我运行Terraform Apply时，我得到以下结果

    $ terraform apply

Apply complete! Resources: 0 added,0 changed,0 destroyed.

Outputs:

combined = {
  "1:/dev/xdba" = {
    "ebs_name" = "/dev/xdba"
    "ebs_size" = [
      "50","20",]
    "ebs_type" = [
      "gp2","gp2",]
    "node_index" = "1"
  }
  "1:/dev/xdbb" = {
    "ebs_name" = "/dev/xdbb"
    "ebs_size" = [
      "50",]
    "node_index" = "1"
  }
  "2:/dev/xdba" = {
    "ebs_name" = "/dev/xdba"
    "ebs_size" = [
      "50",]
    "node_index" = "2"
  }
  "2:/dev/xdbb" = {
    "ebs_name" = "/dev/xdbb"
    "ebs_size" = [
      "50",]
    "node_index" = "2"
  }
  "3:/dev/xdba" = {
    "ebs_name" = "/dev/xdba"
    "ebs_size" = [
      "50",]
    "node_index" = "3"
  }
  "3:/dev/xdbb" = {
    "ebs_name" = "/dev/xdbb"
    "ebs_size" = [
      "50",]
    "node_index" = "3"
  }
}

相反，我希望能够得到如下所示的结果（伪代码）：

combined = {
  "1:/dev/xvdb" = {
    "disk_dev_path" = "/dev/xvda"
    "node_name" = "1"
    "disk_size" = "10"
    "disk_type" = "gp2"
  }
  "1:/dev/xvdc" = {
    "disk_dev_path" = "/dev/xvdb"
    "node_name" = "1"
    "disk_size" = "30"
    "disk_type" = "gp2"
  }
  "2:/dev/xvdb" = {
    "disk_dev_path" = "/dev/xvda"
    "node_name" = "2"
    "disk_size" = "10"
    "disk_type" = "gp2"
  }
  "2:/dev/xvdc" = {
    "disk_dev_path" = "/dev/xvdb"
    "node_name" = "2"
    "disk_size" = "30"
    "disk_type" = "gp2"
  }
  "3:/dev/xvdb" = {
    "disk_dev_path" = "/dev/xvda"
    "node_name" = "3"
    "disk_size" = "10"
    "disk_type" = "gp2"
  }
  "3:/dev/xvdc" = {
    "disk_dev_path" = "/dev/xvdb"
    "node_name" = "3"
    "disk_size" = "30"
    "disk_type" = "gp2"
  }
}

如何实现？

我需要这样做，以便在 for_each 中使用它来创建ec2实例和ebs卷，并在用户使用我们的ec2模块在变量中添加输入时分别附加它们。

解决方法

如果可以的话，也许可以使用带有flatten的 double for-loop 。对我来说似乎更自然。

下面是一个工作示例：

variable "nodes" {
  default = ["1","2","3"]
}

variable "ebs_volumes" {
  default = [
    {
      ebs_name = "/dev/xdba"
      ebs_size = "50"
      ebs_type = "gp2"
    },{
      ebs_name = "/dev/xdbb"
      ebs_size = "20"
      ebs_type = "gp2"
    }
  ]
}

locals {

    node_disks2 = {for idx,value in flatten([for node in var.nodes: 
                   [for volume in var.ebs_volumes:
                    { 
                        node_index = node
                        ebs_name   = volume.ebs_name
                        ebs_size   = volume.ebs_size
                        ebs_type   = volume.ebs_type
                   }]
               ]): idx => value}
}

output "combined" {
  value = local.node_disks2
}

输出：

ombined = {
  "0" = {
    "ebs_name" = "/dev/xdba"
    "ebs_size" = "50"
    "ebs_type" = "gp2"
    "node_index" = "1"
  }
  "1" = {
    "ebs_name" = "/dev/xdbb"
    "ebs_size" = "20"
    "ebs_type" = "gp2"
    "node_index" = "1"
  }
  "2" = {
    "ebs_name" = "/dev/xdba"
    "ebs_size" = "50"
    "ebs_type" = "gp2"
    "node_index" = "2"
  }
  "3" = {
    "ebs_name" = "/dev/xdbb"
    "ebs_size" = "20"
    "ebs_type" = "gp2"
    "node_index" = "2"
  }
  "4" = {
    "ebs_name" = "/dev/xdba"
    "ebs_size" = "50"
    "ebs_type" = "gp2"
    "node_index" = "3"
  }
  "5" = {
    "ebs_name" = "/dev/xdbb"
    "ebs_size" = "20"
    "ebs_type" = "gp2"
    "node_index" = "3"
  }
}