如何批量制作随机机会“功能”

如何解决如何批量制作随机机会“功能”

我正在做一个小型的小游戏，我希望有一个随机的机会来获得某些物品（例如，如果随机数大于10但小于15，那么您将获得某个物品）。这是我已经尝试过导致崩溃的内容。

    set /a chance= %random% %%30+1
if %chance% gtr 10 && lss 30 (
    set /a %nails%+1
    echo You got nails! %chance%
    )

这里的这只是一个测试，但应该使您对我要做什么有所了解。这确实是我想到的唯一方法。如果可以帮助，请执行！ ：）

解决方法

我在该代码中看到了许多问题：

set /a chance= %random% %%30+1
if %chance% gtr 10 && lss 30 (
    set /a %nails%+1
    echo You got nails! %chance%
)

经历他们：

• if语句无效，&&是“如果上一个命令起作用，则执行下一个命令”的连接，而不是常规的“与”运算符。要执行您想做的事情：
  if %chance% gtr 10 if %chance% lss 30。
  有关在and中进行or和cmd的方法，请参见here。语言。

• 命令set /a %nails%+1实际上并没有以任何方式 change nails，它只是对一个表达式求值并将其丢弃。您需要一个赋值来赋值，并且在这种情况下您不需要变量标记：
  set /a "nails += 1"。

• 如果要使用delayedexpansion打印出nails（应该如此），则在变量名称前后都需要一个!：
  echo You got !nails! %chance%。

顺便说一句，您可能会注意到我喜欢引用set /a表达式并将它们很好地隔开-我发现这有助于提高可读性。

---

这将解决一些特定的问题，但是老实说，您最好制作一个 generic 函数，该函数可以为事件发生的可能性提供肯定/否定答案。这样，您可以在需要的任何地方重复使用它。

您可以使用完整程序中如下所示的函数chance来确定是否应基于百分比进行操作：

@echo off
goto :main

:chance
    setlocal enableextensions enabledelayedexpansion
    set retcode=1==0
    set /a "value = %random% %% 100"
    rem echo %value% rem uncomment for debugging
    if %value% lss %2 set retcode=1==1
    endlocal && set %1=%retcode%
    goto :eof

:main
    call :chance result 50
    echo %result%

应同时使用变量名称和要使用的百分比级别调用结果。例如，如果您想基于5％的机会设置变量hasdied，则可以使用以下方式调用它：

call :chance hasdied 5
if %hasdied% goto :handlebeingdead

该函数包含许多可能需要解释的功能：

• setlocal命令确保没有变量转义此功能的范围（但请参见下文），对正确封装很有用。

• 将value变量设置为介于0和99之间的某个随机值。由于%random%会为您提供最多32767的值，因此它的分布并不完美，因此会朝小于68的数字略微倾斜。所说的偏斜可能不足以引起您的关注。

• 然后将该值与您提供的阈值（第二个参数）进行比较，以确定返回值true或false。

• 返回值相当隐蔽，因为它为您提供了表达式，您可以将其放入if语句中，而不必进行显式比较，例如：
  if %hasdied%==1
  通过直接返回这样的相等比较，您可以像布尔值一样使用返回值。

• 然后endlocal清除此函数中所做的所有变量更改，包括返回代码。但是，这一行的替换发生在任何执行之前的 之前，这意味着该行的set部分在替换之前已经具有正确的值retcode endlocal进行清理。这是一种使特定变量“转义”由setlocal/endlocal界定的范围的方法。因此，retcode值位于您作为第一个参数提供的名称的参数中。

• 该命令的set %1=部分是一种允许您指定哪些变量应在调用本身中接收值的方式，类似于myvar = function()。这样您就不必为每个函数分配一个硬编码的变量名，然后在调用后将其分配给另一个变量。

• 当然，goto :eof只是一条return指令。

,

我很确定&&不会批量存在。嵌套if语句：

set /a chance= %random% %%30+1
echo %chance%
IF %chance% GTR 10 (IF %chance% LSS 15 (
     echo You got nails! %chance%
))

,

您不能像这样使用&&。您需要运行两次if语句以同时匹配gtr和lss，您可以将它们一个接一个地放置：

@echo off
set /a chance=%random% %%30+1
if %chance% gtr 10 if %chance% lss 30 (
    set /a nails+=1
    echo You got nails! %chance%
 )

也请注意增加变量set /a nails+=1

的正确方法 ,

if条件方法可以正常工作，但是如果要在许多战利品情况下编写脚本，那会有些笨拙。到目前为止，使用带有宏的数组设置更加容易，该宏可以访问数组中的范围，从而允许您通过使用子字符串修改来更改随机数可以访问的数组的索引，从而简单，轻松地编写滚动不同项目的战利品箱的脚本。演示：

@Echo off
:new
::: -------------------------------------------------------------------||    MACRO DEFINITIONS
Setlocal DisableDelayedExpansion
(Set \n=^^^
%=DNR=%
)
rem  *********************  Display any existing character names for continuation or deletion of characters
If Exist "%TEMP%\%~n0_*_save.bat" (Echo/Your Characters:&Echo/&(For /F "Delims=" %%G in ('Dir "%TEMP%\%~n0_*_save.bat" /B')Do For /F "Tokens=2 Delims=_" %%o in ("%%~nG") Do  < Nul Set /P "=[%%o] ")&Echo/)
:character
Set /P "Name=Name: "
If Exist "%TEMP%\%~n0_%Name%_save.bat" (Echo/[C]ontinue / [D]elete?&For /F "Delims=" %%O in ('Choice /N /C:cd')Do If /I "%%O"=="C" (Goto :playon)Else (Del /P "%TEMP%\%~n0_%Name%_save.bat" & Goto :character))
If "%Name%"=="" Goto :character
:playon
rem ***  Inventory Macro. Displays all elements for the given group and their current values.
rem :::  Usage: %INV:@=$varname[%
    Set "INV=Echo/&(For /F "Tokens=2 Delims==" %%i in ('Set @') Do (Set "VN=%%i"&^< Nul Set /P"=[!VN:$=!:!%%i!] "))&Echo/"
rem ***  Autosave macro. Can be incorperated into other macro's
rem :::  Usage: %Save%
    Set SAVE=(For /F "Tokens=1 Delims==" %%i in ('Set $') Do (If not "!%%i!"=="" Echo/Set "%%i=!%%i!"))^>"%TEMP%\%~n0_!name!_save.bat"
rem ***  Location Display Macro with autosave macro included
rem :::  Usage: %Loc:@=LocationLABEL%
    Set "Loc=(Set "$Loc=@"&Title !$Loc:_= !)&%Save%"
rem ***  Loot box Macro to generate random loot from specified range of an indexed array
rem ***  !random! %%4 + Index# will access an index range between the index # and 4 above the index number.
rem :::  Usage: %Loot:@=index#%
    Set "LOOT=(For /F "UsebackQ Delims=" %%i in (`"Set /A i#=!Random! %%4 + @"`) Do For /F "UsebackQ Delims=" %%v in (`"Set /A v#=!Random! %%3 + 1"`) Do (Set "VN=!$Loot[%%i]:$=!"&Echo/You got %%v !VN!&Set /A "!$Loot[%%i]!+=%%v")) 2> Nul & %SAVE%"
rem ***  the below  macros /I /V and /P are not used in this example. - They are an optional method for defining
rem ***  variables prefixed with $ that automatically saves them for reloading
rem :::  usage: %/I:V=Varname%Input Prompt String:
Set "/I=For %%n in (1 2)Do If %%n==2 (Set /P "$V=!$PromptStr:$=!: "&%Save%)Else Set $PromptStr="
rem :::  usage: %/P:V=Varname%VariableValue
Set "/V=For %%n in (1 2)Do If %%n==2 (Set "$V=!str!"&%Save%)Else Set str="
rem :::  usage: %/A:V=Varname%=Equation
Set "/A=For %%n in (1 2)Do If %%n==2 (Set /A "$V!sum!"&%Save%)Else Set sum="
rem *** Wait prompt Macro
rem :::  usage: %Wait:#=Integer value for time in seconds%Wait Prompt String
Set "Wait=For %%n in (1 2)Do If %%n==2 (Timeout # /Nobreak > Nul & (Pause | Echo/!Output!) 2> Nul )Else Set Output="
rem ***  Array definition macro. Asigns the element names to an indexed Groupname (Array),With each element being assigned an initial 0 value
Rem :::  Usage: %DefArray%{VarGroupName}{Element names as list}
Set DefArray=For %%n in (1 2) Do if %%n==2 (%\n%
 Set "i#=0"%\n%
 For /F "Tokens=1,2 Delims={}" %%G in ("!List!") Do (%\n%
  For %%i in (%%~H) Do (%\n%
   Set "$%%~G[!i#!]=$%%i"%\n%
   Set "$%%i=0"%\n%
   Set /A i#+=1 ^> Nul%\n%
  )%\n%
 )%\n%
) Else Set List=
Set Menu=CLS^&Set "Copt="^&For %%n in (1 2) Do if %%n==2 (%\n%
 Echo/[E]xit%\n%
 For %%G in (!OPTS!)Do (%\n%
  Set "opt=@%%~G"%\n%
  Set "opt=!opt:_= !"^&Set "Opt=!Opt:~,-1!"%\n%
  Set "Copt=!Copt!%%~G"%\n%
  Echo/!Opt! [%%~G]%\n%
 )%\n%
 (For /F "Delims=" %%O in ('Choice /N /C !Copt!E')Do If "%%O"=="E" (Endlocal^&Endlocal^&Set "Name="^&Goto :New) Else (CLS^&Goto :@%%O))%\n%
) Else Set OPTS=
::: -------------------------------------------------------------------||    END MACRO DEFINITIONS

::: -------------------------------------------------------------------||    Example Script
REM // required to be enabled PRIOR to macro Use,AFTER definition.
 Setlocal EnableDelayedExpansion
 %DefArray%{Loot}{Wood Nails Ore Leather Gold Silver Bronze Jade}
 IF Exist "%TEMP%\%~n0_!name!_save.bat" (
  Call "%TEMP%\%~n0_!name!_save.bat"
  Goto :!$Loc!
 )
:Menu
 %Loc:@=Menu%
 %Menu:@=Loot_Box_% "1" "2"
Goto :Menu
:Loot_Box_1
 %Loc:@=Loot_Box_1%
 %Loot:@=0%
 %INV:@=$Loot[%
 %Wait:#=1%
Goto :Menu
:Loot_Box_2
 %Loc:@=Loot_Box_2%
 %Loot:@=4%
 %INV:@=$Loot[%
 %Wait:#=1%Demo wait prompt
Goto :Menu