如何在我的项目中创建每个表单的实例？

如何解决如何在我的项目中创建每个表单的实例？

我已经将应用程序从ADO移植到FireDAC，在源代码上应用了多个RegExp替换，以将ADOQuery，ADOTables，ADOCommands，ADOStoredProcs等转换为相应的FireDAC组件。

它运行良好，但是现在运行该应用程序时，由于持久字段的类型与预期的类型（创建持久字段时从ADO定义的类型）不同，因此许多表格都会引发错误。

我试图列出这些错误，创建所有表单的实例，并使用持久字段打开其数据集，并记录错误。我可以从项目源代码中获取表单列表，但是当我尝试使用FindClass创建每个表单时，出现一条错误消息，提示未找到该类。

还有其他方法可以从其类名创建Form / DataModule吗？

这是我当前的代码：

class procedure TfrmCheckFormularis.CheckDatasets(ProjecteFile: string);
var frmCheckFormularis: TfrmCheckFormularis;
    Projecte: string;
    rm: TMatch;
    cc: TComponentClass; 
    c: TComponent;
    i: integer;
    Dataset: TFDQuery;
begin
  Projecte := TFile.ReadAllText(ProjecteFile);
  frmCheckFormularis := TfrmCheckFormularis.Create(Application);
  try
    with frmCheckFormularis do begin
      Show;
      qryForms.CreateDataSet;
      qryErrors.CreateDataSet;
      // I get a list of all the forms and datamodules on my project
      for rm in TRegEx.Matches(Projecte,'^(?:.* in '')(?<File>.*)(?:'' {)(?<Class>.*)(?:},)',[roMultiline]) do begin
        qryForms.AppendRecord([rm.Groups['File'].Value,rm.Groups['Class'].Value]);
      end;

      // Check every form and datamodule
      qryForms.First;
      while not qryForms.Eof do begin
        cc := TComponentClass(FindClass(qryFormsClass.Value));
        c := cc.Create(frmCheckFormularis);
        try
          for i := 0 to c.ComponentCount - 1 do begin
            if c.Components[i] is TFDQuery then begin
              Dataset := c.Components[i] as TFDQuery;
              // When the Dataset has persistent fields,I open it to check if the persistent fields are correct
              if Dataset.FieldDefs.Count > 1 then begin
                try
                  Dataset.Open;
                except
                  on E: Exception do qryErrors.AppendRecord([c.Name,Dataset.Name,E.Message]);
                end;
              end;
            end;
          end;
        finally
          c.Free;
        end;
        qryForms.Next;
      end;
    end;
  finally
    frmCheckFormularis.Free;
  end;
end;

谢谢。

解决方法

在Delphi中使用“新” RTTI非常容易。以下代码将（希望*）在您的应用程序中为每种表单创建一个实例：

procedure TForm1.Button1Click(Sender: TObject);
var
  Context: TRttiContext;
  &Type: TRttiType;
  InstanceType: TRttiInstanceType;
begin
  Context := TRttiContext.Create;
  for &Type in Context.GetTypes do
  begin
    if (&Type.TypeKind = tkClass) and &Type.IsInstance then
    begin
      InstanceType := TRttiInstanceType(&Type);
      if InstanceType.MetaclassType.InheritsFrom(TForm) and (InstanceType.MetaclassType <> TForm) then
        TFormClass(InstanceType.MetaclassType).Create(Application){.Show}; // optionally show it
    end;
  end;
end;

---

*从技术上讲，它将为TForm的每个适当的后代类创建一个实例。