如果关键字没有失败，则在固定时间内重复执行关键字而不会失败

如何解决如果关键字没有失败，则在固定时间内重复执行关键字而不会失败

在我当前的项目中，我需要检查一个相当复杂的嵌入式系统的以太网连接的稳定性。我们正在使用Robot Framework来执行我们的测试用例。现在，我想对设备执行固定时间的ping操作，并编写了这样的测试用例。

Ping Device
    [Timeout]  1 hour
    FOR   ${i}  IN RANGE  9999999
      Run Keyword And Continue On Failure   Ping Host  192.168.1.100
    END

如果至少一次ping失败，则测试应运行1个小时，并且应该失败。尽管如此，查看ping在多少情况下失败还是不应该放弃的。不幸的是，由于超时，测试也失败了，这似乎是Robot Framework的理智和期望的行为，不应像我一样滥用。

如何仍然可以重复执行一个小时的关键字，而仅在关键字至少失败一次后才失败？

解决方法

要在一定时间内运行关键字，您应该使用Repeat Keyword。请注意，这会生成大量日志，因此建议您查看用户指南中的Removing and flattening keywords章节。

如果一次迭代失败，现在要使测试失败，我建议在用户关键字中使用Run Keyword And Return Status，它将任何失败存储在测试变量中，您可以使用该变量使整个测试用例失败。

下面是一个示例，该示例将每个关键词运行5秒。

*** Test Cases ***
Test OK
    Set Test Variable    ${OVERALL RESULT}    True
    Repeat Keyword    5 sec    Run Keyword And Store Failure   Sleep    1 sec    reason=test
    Run Keyword If    ${OVERALL RESULT} == False    Fail    over all fail
    
Test NOK
    Set Test Variable    ${OVERALL RESULT}    True
    Repeat Keyword    5 sec    Run Keyword And Store Failure   Fail    test
    Run Keyword If    ${OVERALL RESULT} == False    Fail    over all fail
    
Test With Random Failures In It
    Set Test Variable    ${OVERALL RESULT}    True
    Repeat Keyword    5 sec    Run Keyword And Store Failure   Fail Randomly
    Run Keyword If    ${OVERALL RESULT} == False    Fail    over all fail
    
*** Keyword ***
Run Keyword And Store Failure
    [arguments]    ${keyword}    @{args}
    ${status}=    Run Keyword And Return Status    ${keyword}    @{args}
    Run Keyword If    ${status} == False    Set Test Variable    ${OVERALL RESULT}    False

Fail Randomly
    ${numbers}=    Evaluate    random.sample(range(1,200),4)    random
    Run Keyword If    ${numbers}[0]%2 != 0    Fail     fail  randomly
    Sleep    1 sec     reason=reduce log lines