如何解决如何将MARC21-xml转换和过滤为csv?
我有符合MARC21格式的xml文件,如下所示:
(它减少为必要的标签,文件中有许多records
,我只减少为一个)
<?xml version="1.0" encoding="UTF-8"?>
<collection xmlns="http://www.loc.gov/MARC21/slim">
<record>
<controlfield tag="001">EntryID01</controlfield>
<datafield tag="100" ind1="1" ind2=" ">
<subfield code="0">PubID01</subfield>
<subfield code="a">Lastname01,Firstname01</subfield>
</datafield>
<datafield tag="700" ind1="1" ind2=" ">
<subfield code="0">PubID02</subfield>
<subfield code="a">Lastname02,Firstname02</subfield>
</datafield>
<datafield tag="700" ind1="1" ind2=" ">
<subfield code="a">Lastname03,Firstname03</subfield>
</datafield>
</record>
</collection>
我想要一个具有以下命令/输出的csv。
Lastname01,Firstname01 | PubID01 | EntryID01
Lastname02,Firstname02 | PubID02 | EntryID01
Lastname03,Firstname03 | NOPUBID | EntryID01
并非所有数据字段都具有PubID(subfield code="0"
)的信息,如果没有给定的PubID,则应将其写为“ NOPUBID”。
我尝试与此xsltproc
一起使用xsl
:
(我试图先从tag=100
获取数据;但我也需要从tag=700
获取数据)
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:marc="http://www.loc.gov/MARC21/slim"
xmlns="http://www.loc.gov/MARC21/slim"
exclude-result-prefixes="marc">
<xsl:output method="text" encoding="UTF-8" />
<xsl:strip-space elements="*"/>
<xsl:template match="marc:controlfield[@tag=001]">
<xsl:value-of select="controlfield"/>
</xsl:template>
<xsl:template match="marc:datafield[@tag=100]">
<xsl:for-each select="record/datafield">
<xsl:value-of select="controlfield"/>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
但是我拼命失败。任何帮助表示赞赏。
解决方法
我会做的:
XSLT 1.0
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:marc="http://www.loc.gov/MARC21/slim">
<xsl:output method="text" encoding="UTF-8"/>
<xsl:template match="/marc:collection">
<xsl:for-each select="marc:record">
<xsl:variable name="control" select="marc:controlfield[@tag='001']" />
<xsl:for-each select="marc:datafield[@tag='100' or @tag='700']">
<xsl:value-of select="marc:subfield[@code='a']"/>
<xsl:text> | </xsl:text>
<xsl:variable name="pub" select="marc:subfield[@code='0']"/>
<xsl:choose>
<xsl:when test="$pub">
<xsl:value-of select="$pub"/>
</xsl:when>
<xsl:otherwise>NOPUBID</xsl:otherwise>
</xsl:choose>
<xsl:text> | </xsl:text>
<xsl:value-of select="$control"/>
<xsl:text> </xsl:text>
</xsl:for-each>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
版权声明:本文内容由互联网用户自发贡献,该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务,不拥有所有权,不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容, 请发送邮件至 dio@foxmail.com 举报,一经查实,本站将立刻删除。