从维基百科的信息框中抓取一个内部文本

如何解决从维基百科的信息框中抓取一个内部文本

执行需要使用命令按钮的项目应该从网页中提取一些信息。 我选择了 COVID-19 pandemic 的维基百科信息框中的“已确认案例”，我似乎无法编写正确的“getElementsBy..”来提取信息。

 Private Sub AccesswebsitePAN_Click()
WB_PAN.Navigate ("https://en.wikipedia.org/wiki/COVID-19_pandemic")
End Sub

Private Sub GetinfoPAN_Click()
Cells(2,1).Value = WB_PAN.Document.getElementsById("mw-content-text").getElementsByClassName("mw-parser-output").getElementsByTagName("table").getElementsByTagName("tbody").getElementsByTagName("tr")(12).getElementsByTagName("td")(0).Innertext
End Sub

Private Sub WB_PAN_StatusTextChange(ByVal Text As String)

End Sub

解决方法

您在几个阶段忽略了对 getElementsBy 方法返回的集合进行索引。此外，它是 getElementById。我可能会选择一个更易读的较短路径，通过它的类（使用 querySelector）选择表，然后使用 .rows 方法。

你的方式：

Debug.Print WB_PAN.Document.getElementById("mw-content-text").getElementsByClassName("mw-parser-output")(0).getElementsByTagName("table")(0).getElementsByTagName("tbody")(0).getElementsByTagName("tr")(18).getElementsByTagName("td")(0).Innertext

---

替代方案：

Option Explicit

Public Sub CovidCases()

    Dim ie As SHDocVw.InternetExplorer

    Set ie = New SHDocVw.InternetExplorer

    With ie
        .Visible = True
        .Navigate2 "https://en.wikipedia.org/wiki/COVID-19_pandemic"

        While .Busy Or .ReadyState <> READYSTATE_COMPLETE: DoEvents: Wend

        Debug.Print .Document.querySelector(".infobox").Rows(12).innertext
        Debug.Print .Document.querySelector(".infobox").Rows(12).firstchild.nextsibling.innertext
    
        .Quit
    End With
    
End Sub

---

稍微干净一点的是使用 user4596341 中的方法清除节点 html，在处理您的案例之前添加滞后 [4] 引用，以便您拥有更易读的路径

Option Explicit

Public Sub CovidCases()

    Dim ie As SHDocVw.InternetExplorer

    Set ie = New SHDocVw.InternetExplorer

    With ie
        .Visible = True
        .Navigate2 "https://en.wikipedia.org/wiki/COVID-19_pandemic"

        While .Busy Or .ReadyState <> READYSTATE_COMPLETE: DoEvents: Wend

        .Document.querySelector(".infobox tr:nth-of-type(13) sup").innerHTML = vbNullString
        
        Debug.Print .Document.querySelector(".infobox").Rows(12).Cells(1).innertext
        .Quit
    End With
End Sub

---

看到@Sim 的回答提醒我您可以返回 DOM 以获取更清晰的案例计数：

Option Explicit

Public Sub CovidCases()

    Dim ie As SHDocVw.InternetExplorer

    Set ie = New SHDocVw.InternetExplorer

    With ie
        .Visible = True
        .Navigate2 "https://en.wikipedia.org/wiki/COVID-19_pandemic"

        While .Busy Or .ReadyState <> READYSTATE_COMPLETE: DoEvents: Wend

        Debug.Print .Document.querySelector(".infobox tr:nth-of-type(13) sup").PreviousSibling.NodeValue
    
        .Quit
    End With
End Sub

,

由于 ID 是唯一的定位器，您可以尝试在脚本中使用它来获取结果。

Option Explicit
Sub GetCaseCount()
    Const Url$ = "https://en.wikipedia.org/wiki/COVID-19_pandemic"
    Dim Http As Object,elem As Object,S$
    
    With CreateObject("MSXML2.XMLHTTP")
        .Open "GET",Url,False
        .setRequestHeader "User-Agent","Mozilla/5.0 (Windows NT 6.1) AppleWebKit/537.36 (KHTML,like Gecko) Chrome/85.0.4183.121 Safari/537.36"
        .send
        S = .responseText
    End With
    
    With CreateObject("htmlfile")
        .body.innerHTML = S
    
        Set elem = .getElementById("cite_ref-JHU_ticker_5-0")
        Debug.Print elem.ParentNode.innerText
    End With
End Sub

脚本应该可以在不添加对库的任何引用的情况下工作。