如何解决Excel图表上缺少一些但不是全部数据标签
我正在创建一个包含以下代码的气泡图。它会正确地创建带有所有预期数据的图表……除了在某些情况下,只是不显示标签。我已经对值进行了排序和添加,并检查了数据范围和其他内容,但是似乎没有任何理由显示某些标签而有些则不显示。
我有一些屏幕截图,其中包括一个显示该值是在范围内选择的,并且未显示,并且该数据点在该范围内。很难获得所有屏幕截图,但是第三个屏幕截图显示即使在数据标签属性中指定了值,也缺少Co4。
是否有解决此类问题的经验?
.DataLabels.Format.TextFrame2.TextRange.InsertChartField msoChartFieldRange,“ ='活动图表'!$ P $ 18:$ P $”&rgMap.Offset(-1,0).Row,0
我检查了这些条目,但似乎与all labels missing,sunburst chart label issue
无关。解决方法
最后几分钟,在我的电脑上。
这是我为Excel 2013+调整的非常老的代码。
将数据按此顺序分为四列:名称,X,Y和Z(气泡大小)。
以下代码使用此数据创建一个气泡图,忽略任何非数据行(标题行或X,Y或Z为空白的行)。它为每一行创建一个单独的系列,使用第一列作为单点系列的名称,然后应用带有系列名称和气泡大小的标签。
Sub OneRowPerBubbleSeries()
'' Takes 4-column range and constructs Bubble chart
'' Uses one series per row: Columns in order: Name,X,Y,Z
Dim wks As Worksheet
Dim cht As Chart
Dim srs As Series
Dim rng As Range
Dim rng1 As Range
Dim rownum As Integer
Dim bFirstRow As Boolean
Set wks = ActiveSheet
Set rng = Selection
Set cht = wks.Shapes.AddChart2(269,xlBubble3DEffect).Chart
bFirstRow = True
For rownum = 2 To rng.Rows.Count
Set rng1 = rng.Cells(rownum,2).Resize(1,3)
If IsNumeric(rng1.Cells(1,1).Value) And _
IsNumeric(rng1.Cells(1,2).Value) And _
IsNumeric(rng1.Cells(1,3).Value) Then
'' First time: need to do it differently
If bFirstRow Then
cht.SetSourceData Source:=rng1,PlotBy:=xlColumns
bFirstRow = False
Else
Set srs = cht.SeriesCollection.NewSeries
End If
With cht.SeriesCollection(cht.SeriesCollection.Count)
.Values = rng1.Cells(1,2)
.XValues = rng1.Cells(1,1)
.BubbleSizes = "=" & rng1.Cells(1,3).Address _
(ReferenceStyle:=xlR1C1,External:=True)
.Name = rng.Cells(rownum,1)
.HasDataLabels = True
With .DataLabels
.Position = xlLabelPositionRight
.ShowSeriesName = True
.ShowValue = False
.ShowBubbleSize = True
.NumberFormat = "$#,##0"
End With
End With
End If
Next
End Sub
版权声明:本文内容由互联网用户自发贡献,该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务,不拥有所有权,不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容, 请发送邮件至 dio@foxmail.com 举报,一经查实,本站将立刻删除。