将汇总数据从Excel加载到ADODB.RecordSet中

如何解决将汇总数据从Excel加载到ADODB.RecordSet中

我正在尝试使用SQL SELECT命令通过VBA宏将特定工作表中的Excel文件中的数据加载到ADODB.RecordSet中。 Excel工作表上有几列，而我并不需要全部。

例如： col.A =姓，col.B =名称，col.C = IDPerson，[....不需要的列]，N。Col =老板

目的是获取以下各项的汇总数据记录集： col.C = IDPerson，col.N = Boss。 下图中突出显示的字段。

我想创建一个RecordSet，并用黄色突出显示列的聚合（非重复）数据。

显然，也可以通过加载矩阵来解决此问题，但是，在这种情况下，我将必须构建一种加载算法来“清除”数据中的所有重复，然后，我将不得不提供带有以下内容的搜索功能：一些循环。 因此，我认为如果可以通过读取WorkSheet来加载所需的所有数据，就好像它是数据表一样，然后对其进行查询以提取所需的数据并将所有内容加载到ADODB中.RecordSet将会更多搜索数据（例如过滤数据）也很有效。

下面，我报告我的代码，该代码将加载工作表中的所有数据：

Public Sub LoadRecordSet(ByVal LastRow As Long,ByVal LastCol As Integer)
    Dim cnt As ADODB.Connection
    Dim rsData As ADODB.Recordset
    Dim strSQL As String
    Dim strTMP As String

    strTMP = Cells(LastRow,LastCol).Address
    strTMP = Replace(strTMP,"$","")

    Set cnt = New ADODB.Connection
    cnt.Mode = adModeRead
    cnt.ConnectionString = "Provider=Microsoft.ACE.OLEDB.12.0;" & _
                            "Data Source=" & ActiveWorkbook.FullName & ";" & _
                            "Extended Properties=""Excel 12.0 Macro;HDR=Yes;"";"
    cnt.Open
    
    strSQL = "SELECT * FROM [Sheet1$C2:" & strTMP & "]"
    Set rsData = New ADODB.Recordset
    With rsData
        Set .ActiveConnection = cnt
        .Source = strSQL
        .CursorLocation = adUseClient
        .CursorType = adOpenKeyset
        .LockType = adLockOptimistic
        .Open
    End With
    
    'TODO - Something with rsData for filtering or to research
    
    'GC
    If Not rsData Is Nothing Then
        If rsData.State <> adStateClosed Then rsData.Close
        Set rsData = Nothing
    End If
    If Not cnt Is Nothing Then
        If cnt.State <> adStateClosed Then cnt.Close
        Set cnt = Nothing
    End If
End Sub

我的问题是：“如果我只想如上所述加载一些列并进行汇总，以使它们在数据中没有重复呢？”

例如，如果我想加载类似 SELECT [cod.fiscale]，来自[MySheet $ A3：N480] GROUP BY [cod.fiscale]，负责

有可能吗？ 非常感谢。

解决方法

我改进了现在可以正常工作的代码：

Public Sub CaricaDati()
    Dim cnt As ADODB.Connection
    Dim rsDati As ADODB.Recordset
    Dim strSQL As String
    Dim strTMP As String
    Dim i As Integer

on Error GoTo Error_Handler
    Range("A3").Select
    g_BOLTS_UltimaRiga = LasRow
    Call LastCol
    strTMP = Cells(g_LastRow,g_LastCol).Address
    strTMP = Replace(strTMP,"$","")

    Set cnt = New ADODB.Connection
    cnt.Mode = adModeRead
    cnt.ConnectionString = "Provider=Microsoft.ACE.OLEDB.12.0;" & _
                            "Data Source=" & ActiveWorkbook.FullName & ";" & _
                            "Extended Properties=""Excel 12.0 Macro;HDR=Yes;"";"
    cnt.Open
    
    'strSQL = "SELECT * FROM [2$C2:" & strTMP & "]"
    strSQL = "SELECT cf,responsabile FROM [2$C2:" & strTMP & "] GROUP BY cf,responsabile"
    Set rsDati = New ADODB.Recordset
    With rsDati
        Set .ActiveConnection = cnt
        .Source = strSQL
        .CursorLocation = adUseClient
        .CursorType = adOpenKeyset
        .LockType = adLockOptimistic
        .Open
    End With
    
    If Not (rsDati.BOF And rsDati.EOF) Then
        strTMP = ""
        For i = 0 To rsDati.Fields.Count - 1
            strTMP = strTMP & rsDati.Fields(i).Name & ";"
        Next i
        Debug.Print strTMP
        
        strTMP = ""
        rsDati.MoveFirst
        Do While Not rsDati.EOF
            strTMP = ""
            For i = 0 To rsDati.Fields.Count - 1
                strTMP = strTMP & rsDati.Fields(i).Value & ";"
            Next i
            Debug.Print strTMP
            rsDati.MoveNext
        Loop
    End If
    
Uscita:
On Error Resume Next
    'GC
    If Not rsDati Is Nothing Then
        If rsDati.State <> adStateClosed Then rsDati.Close
        Set rsDati = Nothing
    End If
    If Not cnt Is Nothing Then
        If cnt.State <> adStateClosed Then cnt.Close
        Set cnt = Nothing
    End If
Exit Sub
Error_Handler:
        On Error GoTo 0
        MsgBox Err.Number & " - " & Err.Description,vbOKOnly + vbCritical,"ERRORE IMPREVISTO"
        GoTo Uscita
    End Sub