禁用所有文本框字段的快速方法，使用编辑按钮解锁

如何解决禁用所有文本框字段的快速方法，使用编辑按钮解锁

Vb.net是否可以快速禁用表单中的所有可编辑字段（文本框，复选框等）？我正在尝试防止数据被“意外”覆盖。我的用户必须单击编辑按钮才能“解锁”字段并使它们可编辑，并且用户必须按保存按钮来更新数据库并再次锁定字段。

到目前为止，我只找到了一个手动输入，以使每个文本框和复选框（在表单的不同选项卡中大约有30个）只读值变为true，如果我单击编辑按钮则将其禁用。有关如何执行此操作的任何建议？我可以更快地做到“每个人”吗？我将如何制定代码？我发现2007年有此摘要的文章：

For Each control As Control In Me.Controls

If TypeOf (control) Is TextBox Then

CType(control,TextBox).ReadOnly = True

End If
Next

但是我一口气需要所有类型的字段。

感谢您提供有关此主题的任何建议。我是初学者。

解决方法

这将禁用TextBox中直接添加到CheckBox中的每个TabPage和每个TabControl1：

For each tp As TabPage In TabControl1.TabPages
    For Each tb In tp.Controls.OfType(Of TextBox)()
        tb.Enabled = False
    Next

    For Each cb In tp.Controls.OfType(Of CheckBox)()
        cb.Enabled = False
    Next
Next

参考this question

如果将其放在名为ControlExt.vb的模块中：

Imports System.Runtime.CompilerServices
Module ControlExt

<Extension()>
Public Function GetAllChildren(Of T As Control)(parentControl As Control) As IEnumerable(Of T)
    Dim controls = parentControl.Controls.Cast(Of Control)
    Return controls.SelectMany(Of Control)(Function(ctrl) _
        GetAllChildren(Of T)(ctrl)) _
        .Concat(controls) _
        .Where(Function(ctrl) ctrl.GetType() = GetType(T)) _
    .Cast(Of T)
End Function

End Module

然后您可以在课堂上这样做：



Class WhateverForm

  Private _allTextboxes as List(Of TextBox)

  Public Sub New() 'in the constructor

    InitializeComponent()

    _allTextboxes = Me.GetAllChildren(Of TextBox).ToList()
  End Sub

这意味着您表单上的所有文本框（无论位于何处的子面板，组框的选项卡等）中的所有文本框现在都位于列表中。您可以在编辑按钮单击处理程序中进行此操作：>

_allTextboxes.ForEach(Sub(b) b.ReadOnly = False)

当然，请在“保存”按钮中执行推论ReadOnly = True。您不必将其限制在文本框内； GetAllChildren可以找到任何东西-也许您也想锁定复选框-拥有_allCheckboxes，GetAllChildren(Of CheckBox)的另一个列表，并在ForEach中设置Enabled =等

我要指出，ReadOnly和Enabled稍有不同，如果您要在UI中将内容设为灰色（对于ReadOnly，则为“一半灰色”），则作为UX指针。有一些解释为什么该选项显示为灰色/如何启用它的信息。对于用户来说，他们不必立即单击“启用”，并且如果您不希望技术支持人员致电“我在名称框中单击，我会看到光标闪烁，但是当我键入时什么也没发生！”，这不会立即变得明显。然后通过“查看模式：要启用此数据的编辑，请单击[编辑]”等来对他们进行微调。

尝试一下：

For Each control As Control In Me.Controls
  Try 
    CType(control,TypeOf(control)).ReadOnly = True
  Catch 
    ' Do nothing
  End Try
Next

感谢 GetAllChildren 函数。我想我会分享它的延续，以便您可以根据标签锁定所有常用控件。

Public Sub LockControls(ByVal frm_Form As Form,ByVal bln_Lock As Boolean,ByVal str_TAG As String)

    Dim allTextboxes As List(Of TextBox)
    Dim allComboBoxes As List(Of ComboBox)
    Dim allDateTimePickers As List(Of DateTimePicker)
    Dim allDataGrids As List(Of DataGridView)
    Dim allCheckBoxes As List(Of CheckBox)
    Dim allListBoxes As List(Of ListBox)
    Dim allButtons As List(Of Button)

    Dim blnEnable As Boolean
    Dim blnReadonly As Boolean

    If bln_Lock Then ' we need to lock controls
        blnEnable = False
        blnReadonly = True
    Else
        blnEnable = True
        blnReadonly = False
    End If

    allTextboxes = frm_Form.GetAllChildren(Of TextBox).ToList
    For Each CTL In allTextboxes
        If ContainsTag(CTL.Tag,str_TAG) Then
            CTL.ReadOnly = blnReadonly
        End If
    Next

    allComboBoxes = frm_Form.GetAllChildren(Of ComboBox).ToList
    For Each CTL In allComboBoxes
        If ContainsTag(CTL.Tag,str_TAG) Then
            CTL.Enabled = blnEnable
        End If
    Next

    allCheckBoxes = frm_Form.GetAllChildren(Of CheckBox).ToList
    For Each CTL In allCheckBoxes
        If ContainsTag(CTL.Tag,str_TAG) Then
            CTL.Enabled = blnEnable
        End If
    Next

    allButtons = frm_Form.GetAllChildren(Of Button).ToList
    For Each CTL In allButtons
        If ContainsTag(CTL.Tag,str_TAG) Then
            CTL.Enabled = blnEnable
        End If
    Next

    allDateTimePickers = frm_Form.GetAllChildren(Of DateTimePicker).ToList
    For Each CTL In allDateTimePickers
        If ContainsTag(CTL.Tag,str_TAG) Then
            CTL.Enabled = blnEnable
        End If
    Next

    allDataGrids = frm_Form.GetAllChildren(Of DataGridView).ToList
    For Each CTL In allDataGrids
        If ContainsTag(CTL.Tag,str_TAG) Then
            CTL.ReadOnly = blnReadonly
        End If
    Next

    allListBoxes = frm_Form.GetAllChildren(Of ListBox).ToList
    For Each CTL In allListBoxes
        If ContainsTag(CTL.Tag,str_TAG) Then
            CTL.Enabled = blnEnable
        End If
    Next

End Sub

Private Function ContainsTag(fulltag As String,searchTag As String) As Boolean
    Dim found As Boolean
    Dim tags As String() = Nz(fulltag,"").Split(New Char() {","c})

    For Each tag In tags
        If tag = searchTag Then
            found = True
        End If
    Next

    Return found
End Function

Public Function Nz(ByVal Value As Object,Optional ByVal DefaultVal As Object = "") As Object
    If Value Is Nothing OrElse IsDBNull(Value) Then
        Return DefaultVal
    Else
        Return Value
    End If
End Function

禁用所有文本框字段的快速方法，使用编辑按钮解锁

如何解决禁用所有文本框字段的快速方法，使用编辑按钮解锁

解决方法

相关推荐