AppleScript中的CR与LF

如何解决AppleScript中的CR与LF

我使用AppleScript处理从Keynote演示者笔记中获取的文本。通常，我逐段浏览文本，但是最近我发现一个实例，其中使用了“软返回”（ASCII 13 aka CR）而不是实际返回值（ASCII 10 aka LF）。

我现在尝试对文本进行预处理，以摆脱CR而改用LF，但是以下方法由于没有明显的原因而失败：

on purgeCR(aText)
     set my text item delimiters to {ASCII character 13}
     return text items of aText as text
end purgeCR

当我用带有CR和LF的文本填充它们时，它们都将保持不变，我真的不知道为什么。由于某些原因，CR不能用作文本​​项定界符。

另一种尝试是使用shell：

set z to do shell script "echo " & quoted form of a & " | tr '\r' '\n' " without altering line endings

也没有运气。

由于某种原因，CR搞砸了AppleScript处理文本的能力，或者我只是看不到很明显的东西，因为很愚蠢。

我有一个工作脚本，它逐个字符地处理文本，但是必须有一种更简单（更快）的方法！

解决方法

在脚本编辑器中运行的以下示例 AppleScript 代码，将替换回车和换行符：

set foo to "This text contains\rinstead of\n which is what is expected.\rHow do I get rid of them?"

set AppleScript's text item delimiters to return
set bar to text items of foo
set AppleScript's text item delimiters to linefeed
set foo to text items of bar as text
set AppleScript's text item delimiters to {}

return foo

---

更新为发表评论：

作为在 macOS Catalina 10.15.6下使用 Keynote 版本10.2（7028.0.88）的简单测试，我创建了一个带有幻灯片的新演示文稿，这是唯一的演示文稿窗口会在主题提示中打开，而不会修改其默认设置。

在脚本编辑器中，我运行了以下示例 AppleScript 代码：

set foo to "foo\rbar"

ASCII number of character 4 of foo

tell application "Keynote" to tell slide 1 of front document
    set presenter notes to foo
    set bar to presenter notes
end tell

ASCII number of character 4 of bar

tell application "Keynote" to tell slide 1 of front document
    set foo to presenter notes
end tell

ASCII number of character 4 of foo

set AppleScript's text item delimiters to return
set bar to text items of foo
log bar
set AppleScript's text item delimiters to linefeed
set foo to text items of bar as text
log foo
set AppleScript's text item delimiters to {}

ASCII number of character 4 of foo

tell application "Keynote" to tell slide 1 of front document
    set presenter notes to foo
    set bar to presenter notes
end tell

ASCII number of character 4 of bar

在脚本编辑器的答复窗格中，显示以下内容：

tell current application
    ASCII number "
"
        --> 13
end tell
tell application "Keynote"
    set presenter notes of slide 1 of document 1 to "foo
bar"
    get presenter notes of slide 1 of document 1
        --> "foo
bar"
end tell
tell current application
    ASCII number "
"
        --> 13
end tell
tell application "Keynote"
    get presenter notes of slide 1 of document 1
        --> "foo
bar"
end tell
tell current application
    ASCII number "
"
        --> 13
    (*foo,bar*)
    (*foo
bar*)
    ASCII number "
"
        --> 10
end tell
tell application "Keynote"
    set presenter notes of slide 1 of document 1 to "foo
bar"
    get presenter notes of slide 1 of document 1
        --> "foo
bar"
end tell
tell current application
    ASCII number "
"
        --> 10
end tell
Result:
10

如您所见，回车确实被换成换行符。

如果您没有得到相同的结果，那么我唯一的建议是在将主讲人注释设置为具有笔架的 text 之前返回并替换为换行符，首先将演示者注释设置为""，然后将其设置为更正的文本。