AppleScript错误无法将路径变成类型别名

如何解决AppleScript错误无法将路径变成类型别名

我正在尝试设置一个AppleScript，该脚本将从桌面上的txt文件（mockUPPath.txt）获取路径，从理论上讲，这将允许我附加jpg。文件夹和jpg的名称将会更改，因此我无法对其进行硬编码。我还从设法工作的桌面上的另一个文本文件中获取了电子邮件的正文。我可以用它来构建电子邮件，但找不到并附加jpg。

mockUPPath.txt文件中的文本如下所示：Name_Mock-up / 555.jpg。 jpg 555.jpg位于桌面上的“ Name_Mock-up”文件夹中 这是我到目前为止（下）的内容，有人知道我要去哪里了吗？

set AppleScript's text item delimiters to return
set theFile to ((path to desktop as text) & "mockUPText.txt")
set theData to paragraphs of (read file theFile)

set myPath to ((path to desktop as text) & "mockUPPath.txt")
set thePath to paragraphs of (read file myPath)
set newPath to (POSIX path of (path to desktop folder)) & thePath


--Email

set theMessageSubject to "Test email"
set theRecipient to "[e-mail]"
set theMessageContent to theData
set theMessageAttachment to newPath

tell application "Mail"
    activate
    set theMessage to make new outgoing message with properties {visible:true,subject:theMessageSubject,content:theMessageContent & linefeed & linefeed}
    tell theMessage
        make new to recipient at end of to recipients with properties {address:theRecipient}
        make new attachment with properties {file name:theMessageAttachment as alias} at after the last word of the last paragraph
    end tell
end tell

解决方法

与读/写API交互的最可靠方法首先是强制设置«class furl»的路径并删除file关键字。

所有大多数文本文件中的第二个都是UTF 8编码的。如果是这样，请as «class utf8»

发生此错误是因为您不能强制使用POSIX路径来别名。您需要额外的步骤

Text item delimiters毫无意义，将正文作为一个字符串读取，并获得thePath的第一项。

set theFile to ((path to desktop as text) & "mockUPText.txt") as «class furl»
set theData to (read theFile as «class utf8»)

set myPath to ((path to desktop as text) & "mockUPPath.txt") as «class furl»
set thePath to paragraphs of (read myPath as «class utf8»)
set newPath to (POSIX path of (path to desktop folder)) & item 1 of thePath

set newAlias to POSIX file newPath as alias -- if the file doesn't exist you'll get an error


--Email

set theMessageSubject to "Test email"
set theRecipient to "[e-mail]"
set theMessageContent to theData
set theMessageAttachment to newAlias

tell application "Mail"
    activate
    set theMessage to make new outgoing message with properties {visible:true,subject:theMessageSubject,content:theMessageContent & linefeed & linefeed}
    tell theMessage
        make new to recipient at end of to recipients with properties {address:theRecipient}
        make new attachment with properties {file name:theMessageAttachment} at after the last word of the last paragraph
    end tell
end tell

,

根据您在OP中显示的信息，以下示例 AppleScript 代码适用于我，并在脚本编辑器中进行了测试。

首先，我做了以下事情：

• 在名为 Name_Mock-up 的桌面上创建了文件夹，其中包含示例 脚本编辑器中的AppleScript 代码将其命名为 555.jpg
• 在我的桌面上创建了一个文件，名为 mockUPText.txt ，其中一行是 text ， Name_Mock-up / 555.jpg 。

运行了示例 AppleScript 代码：

set theFile to ((path to desktop as text) & "mockUPText.txt") as alias
set theData to read theFile

set myPath to theFile
set thePath to read myPath
set newPath to (POSIX path of (path to desktop folder)) & thePath

set theMessageSubject to "Test email"
set theRecipient to "[e-mail]"
set theMessageContent to theData
set theMessageAttachment to newPath

tell application "Mail"
    activate
    set theMessage to make new outgoing message with properties {visible:true,content:theMessageContent & linefeed & linefeed}
    tell theMessage
        make new to recipient at end of to recipients with properties {address:theRecipient}
        make new attachment with properties {file name:theMessageAttachment} at after the last word of the last paragraph
    end tell
end tell

---

以下是运行示例 AppleScript 代码的结果的屏幕截图：

注意：所有人都说过，我不一定会以这种方式对其进行 code ，而只是提出来纠正某些 code 您最初是按照我对您的OP的评论中的一部分提到的。