我需要在Clojure函数的末尾重新分配变量的值

如何解决我需要在Clojure函数的末尾重新分配变量的值

我是Clojure领域的新手，并且对函数式编程还是一个新手。我正在尝试编写一个函数，该函数计算给定的词汇表（只是单词列表）和一组概率（每个单词出现的概率）下特定单词列表出现的概率。我使用的是简化的词袋模型，并且每个结果都假定是独立的。

例如，给定：

词汇量（相关概率）：睡眠（0.3），狗（0.09），a（0.2），（0.05），牛（0.17），船（0.04），一切（0.15）
句子：(list 'the 'dog 'boat)

我希望它计算（0.05）*（0.09）*（0.04）= 0.00018

我已经有一个函数可以提取每个单词的概率，并且可以按预期工作。我将其粘贴在这里以供参考：

(defn lookup-probability [w outcomes probs]
  (if (not= w (first outcomes)) ;;if the current element is not equal to the word we're looking for...

    (lookup-probability w (rest outcomes) (rest probs)) ;;...keep cycling through the vocabulary

    (first probs) ;;once we find the right word,fetch the corresponding entry in the probability list
  )
)

这是我感到困惑的部分：

(def sentenceprobs '()) ;;STEP 1
(defn compute-BOW-prob [sentence vocabulary probabilities]
  (if (not(empty? sentence))
      (def sentenceprobs (conj sentenceprobs (lookup-probability (first sentence) vocabulary probabilities)) ;;STEP 2
      (compute-BOW-prob (rest sentence) vocabulary probabilities) ;;STEP 3
    )
    (product sentenceprobs) ;;STEP 4 (the product function just multiplies all the elements of a list together)
  )
)

这是我的总体策略：

首先定义一个空列表“ sentenceprobs”，我将在其中存储句子中每个单词的概率
如果句子是非空的，则将第一个单词的概率添加到列表“句子概率”中
在句子的其余部分上递归调用函数（减去我们刚发现的概率，ofc）
一旦句子为空，即我们获取了每个单词的概率，则返回“句子概率”中所有元素的乘积

如果我只想使用一次该功能，则可以正常工作。但是，如果我想多次调用它，则句子概率仍然包含上一次调用的所有概率。该功能仍将运行，但是它给了我错误的概率（小得多的东西）。 因此，我尝试在函数的最后重置句子问题的值，以使其“可重用”：

(def sentenceprobs '())
(defn compute-BOW-prob [sentence vocabulary probabilities]
  (if (not(empty? sentence))
      (def sentenceprobs (conj sentenceprobs (lookup-probability (first sentence) vocabulary probabilities))
      (compute-BOW-prob (rest sentence) vocabulary probabilities)
    )
    (product sentenceprobs)
  )
  (def sentenceprobs '()) ;; <---THIS IS WHAT I ADDED
)

执行此操作时，该函数完全不返回任何内容。从某种意义上讲，这是预料之中的，因为该函数必须在此列表上返回一个操作，因此将其清空可能会造成混乱。但是我认为，由于我要在退出if语句之前递归并返回一个值，所以这不是问题。我想我弄错了哈哈。

我已经在互联网上闲逛了一些，看来def并不是Clojure的工作方式，但是我不知道如何解决。有谁知道我该怎么做？非常感谢。

解决方法

在Alan的回应上建立一点点。在这种情况下，您有一个值列表（一个句子中的单词），并且想要计算一个合计（根据先前的一些概率计算，所有这些单词一起出现的概率）。我假设您像Alan一样像地图一样建立了概率表（尽管我使用字符串而不是关键字作为关键字）。

要执行聚合，我们将使用reduce，它允许您将集合折叠为单个值。为此，它使用一个带有累加器的函数和一个值，并将其应用于集合中的所有元素。

代码如下：

(def prob-map
  {"sleep"      0.3
   "dog"        0.09,"a"          0.2,"the"        0.05,"cow"        0.17,"boat"       0.04,"everything" 0.15})

(defn compute-BOW-prob [probs sentence]
  (reduce (fn [acc word]
            (* acc (get probs word 1)))
          1
          (clojure.string/split sentence #"\s")))

(compute-BOW-prob prob-map "the dog boat")
;; => 1.7999999999999998E-4

它与Alan的解决方案基本相同，但是它没有单独的步骤来乘以概率（这还为您节省了一个中间列表，在这种情况下，这很可能不是问题，但是如果您有非常大的输入）。

上面的代码将概率图和一个句子作为输入。然后，它拆分句子（我只是使用空格作为分隔符，但是您可以根据需要添加标点符号和停用词），并使用提供的功能缩小列表的范围。该函数采用一个累加器（acc）和列表中的一个元素（word），然后将累加器乘以该单词的概率（如果找不到该单词，则为1，...您当然可以采取不同的方法来处理此问题）。函数下方的1是acc将采用的初始值。

这有助于阐明您的想法！通常，您根本不需要修改变量，并且绝对不应在所有内部函数中都使用def。另外，请尝试避免显式使用全局变量，而让函数将其用作参数。

请参阅this template project。它显示了我喜欢如何组织项目（只需克隆存储库并开始编码！）。尤其要研究the list of documentation，以了解Clojure语言与命令式语言之间的区别。

我将通过使用地图来保存概率来解决这个问题。然后，您可以使用mapv（或仅使用map）将概率从地图中拉出到矢量（或列表）中。然后使用(apply * ...)计算乘积：

(ns tst.demo.core
  (:use tupelo.test)
  (:require
    [tupelo.core :as t]))

(def prob-map
  {:sleep      0.3
   :dog        0.09,:a          0.2,:the        0.05,:cow        0.17,:boat       0.04,:everything 0.15})

(defn calc-prob
  [words]
  (let [probs (mapv #(get prob-map %) words)]
    (apply * probs)))

(dotest
  (let [sentence [:the :dog :boat]
        result   (calc-prob sentence)
        expected (t/spyx (* 0.05 0.09 0.04))  ; spyx displays the value
        ]
    (is (t/rel=  result expected :digits 8))))

您可以通过以下方式运行它：

> lein clean
> lein test

产生输出：

--------------------------------------
   Clojure 1.10.2-alpha1    Java 15
--------------------------------------

Testing tst.demo.core
(* 0.05 0.09 0.04) => 1.7999999999999998E-4

Ran 2 tests containing 1 assertions.
0 failures,0 errors.

就像您提到的那样，这不是使用def的方法。您尝试创建一个列表，然后附加来自多个断开连接的函数调用的内容。这是命令式语言的方式，但不是功能性语言的方式。在这里，我们宁愿匿名创建一个列表，并将其作为函数的返回值传递。

我尝试运行您的代码，但是compute-BOW-prob没有编译，所以我不确定您希望它如何工作。

无论如何，这里有一些改进点。

在第一个版本中，我尝试对您的原始设计进行尽可能少的修改（尽管必须def）。在您的设计中，您尝试仅以基本情况（空句子）退还产品。对于递归函数来说，这不是一个很好的设计，它们应该始终返回相同类型的值。在comp-bow中，这是通过返回1的基本情况并随着您在调用函数中向上移动而连续乘以概率来解决的。

(defn comp-bow [sentence vocabulary probabilities]
  (if (not (empty? sentence))
    (* (comp-bow (rest sentence) vocabulary probabilities)
       (lookup-probability (first sentence) vocabulary probabilities))
    1))

我不知道您是否熟悉let。这就是在Clojure中分配内容的结束时间，分配只存在于let列表中。该设计与您的设计非常相似，因为它创建了概率列表，并且仅在最后执行乘法。（我使用apply *而不是您的product。在这里，我将返回列表的函数和返回乘积的函数分开（如上所述）。此处的let仅用于说明目的。

(defn comp-bow2 [sentence vocabulary probabilities]
  (apply * (comp-bow2-sub sentence vocabulary probabilities)))

(defn comp-bow2-sub [sentence vocabulary probabilities]
  (if (not (empty? sentence))
    (let [sentenceprobs (comp-bow2-sub (rest sentence) vocabulary probabilities)
          word-prob (lookup-probability (first sentence) vocabulary probabilities)]
      (conj sentenceprobs word-prob))))

如果要进行递归函数调用，您应该了解recur。由于Clojure在JVM上运行，因此如果您执行许多递归函数调用，可能会遇到麻烦。 recur通过在调用时删除当前堆栈框架来避免这种情况，但是您只能将recur调用放在函数的最后，这样在通过调用函数返回时不需要使用函数堆栈框架。这有点类似于我的第一个建议，但区别是我开始将概率直接乘以1，以便可以使用recur。

(defn comp-bow3 [sentence vocabulary probabilities]
  (comp-bow3-sub sentence vocabulary probabilities 1))

(defn comp-bow3-sub [sentence vocabulary probabilities product]
  (if (empty? sentence)
    product
    (recur (rest sentence) vocabulary probabilities
           (* product (lookup-probability (first sentence) vocabulary probabilities)))))

您不必使用递归来完成此操作（即使它很有趣）。 mvarela建议的基于reduce的解决方案对于大多数人来说可能更清晰。

我需要在Clojure函数的末尾重新分配变量的值

如何解决我需要在Clojure函数的末尾重新分配变量的值

解决方法

相关推荐