使用 Indy 10 发送字节

如何解决使用 Indy 10 发送字节

我正在尝试使用 Indy 10 在两个 delphi 2010 应用程序之间发送字节，但没有成功。接收的字节与发送的字节不同。这是我的示例代码：
应用1，发送按钮点击：

var s:TIdBytes;
begin
    setlength(s,3);
    s[0]:=48;
    s[1]:=227;
    s[2]:=0;
    IdTCPClient.IOHandler.WriteDirect(s);  // or .Write(s);
end;

应用 2，idtcpserver 执行事件（第一次尝试）：

procedure TForm1.IdTCPServerExecute(AContext: TIdContext);
var rec:TIdBytes;
     b:byte;
begin
    SetLength(rec,0);
    b:=AContext.Connection.IOHandler.ReadByte;
    while b<>0 do
    begin 
         setlength(rec,length(rec)+1);
         rec[length(rec)-1]:=b;
         b:=AContext.Connection.IOHandler.ReadByte;
    end;

    // Here I expect rec[0] = 48,rec[1]=227,rec[2]=0.
    // But I get: rec[0] = 48,rec[1]=63,rec[2]=0.   Rec[1] is incorrect
    // ... rest of code
end;

应用 2，idtcpserver 执行事件（第二次尝试）：

procedure TForm1.IdTCPServerExecute(AContext: TIdContext);
var c:ansistring;
begin
    c:= AContext.Connection.IOHandler.ReadLn(Char(0));

    // Here I expect c[0] = 48,c[1]=227,c[2]=0.
    // But I get: c[0] = 48,c[1]=63,c[2]=0.   c[1] is incorrect
    // ... rest of code
end;

最奇怪的是这些应用程序是几年前用 Delphi 5 开发的，它们运行良好（使用 readln(char(0)）。当我将这两个应用程序转换为 Delphi 2010 时，它们停止工作。我认为这是由于 unicode字符串，但我还没有找到解决方案。

解决方法

首先，不要直接使用 TIdIOHandler.WriteDirect() ，而是只使用 TIdIOHandler.Write() 重载。

其次，您的第一次尝试代码不可能产生您声称的结果。 TIdIOHandler.Write[Direct](TIdBytes) 和 TIdIOHandler.ReadByte() 仅对原始字节进行操作，字节按原样传输。因此，您可以保证准确获得发送的内容，字节值根本不可能像您建议的那样更改。

但是，您的第二次尝试代码当然可以产生您声称的结果，因为 TIdIOHandler.ReadLn() 将读取字节并将它们转换为 UnicodeString，您是然后分配给一个 AnsiString，这意味着接收到的数据正在经历 2 次有损字符集转换：

首先，使用 UnicodeString 属性作为解码字符集，将接收到的字节按原样解码为 UTF-16 TIdIOHandler.DefStringEncoding，默认设置为 IndyTextEncoding_ASCII （您可以将其更改为例如 IndyTextEncoding_8bit）。字节 227 超出 ASCII 范围，因此该字节被解码为 Unicode 字符 '?' (#63)，这表明发生了数据丢失。
然后，将 UnicodeString 分配给 AnsiString，它使用 RTL 的默认字符集将 UTF-16 数据转换为 ANSI（默认设置为用户的操作系统区域设置，但可以使用 System.SetMultiByteConversionCodePage() 函数更改）。在这种情况下，不会再发生损失，因为 UnicodeString 包含 US-ASCII 范围内的字符，这些字符会按原样转换为 ANSI。

话虽如此，我不建议像您那样在手动循环中使用 TIdIOHandler.ReadByte()。尽管 TIdIOHandler 没有用于字节的 WaitFor() 方法，但仍然有一种更有效的方法来解决这个问题，例如：

procedure TForm1.IdTCPServerExecute(AContext: TIdContext);
var
  rec: TIdBytes;
  LPos: Integer;
begin
  SetLength(rec,0);

  // adapted from code in TIdIOHandler.WaitFor()...
  with AContext.Connection.IOHandler do
  begin
    LPos := 0;
    repeat
      LPos := InputBuffer.IndexOf(Byte(0),LPos);
      if LPos <> -1 then begin
        InputBuffer.ExtractToBytes(rec,LPos+1);
        { or,if you don't want the terminating $00 byte put in the TIdBytes:
        InputBuffer.ExtractToBytes(rec,LPos);
        InputBuffer.Remove(1);
        }
        Break;
      end;
      LPos := InputBuffer.Size;
      ReadFromSource(True,IdTimeoutDefault,True);
    until False;
  end;

  // ... rest of code
end;

或者：

procedure TForm1.IdTCPServerExecute(AContext: TIdContext);
var
  rec: string
begin
  rec := AContext.Connection.IOHandler.ReadLn(#0,IndyTextEncoding_8Bit);
  // ... rest of code
end;

是的，Delphi 5 中的 string 类型是 AnsiString，但在 Delphi 2009 中更改为 UnicodeString。

但即便如此，在 Delphi 之前的 Unicode 版本中，Indy 10 中的 TIdIOHandler.ReadLn() 仍会读取原始字节并使用 TIdIOHanlder.DefStringEncoding 将它们转换为 Unicode。然后它会在退出之前将该 Unicode 数据转换为 AnsiString，使用 TIdIOHandler.DefAnsiEncoding 属性作为转换字符集，默认设置为 IndyTextEncoding_OSDefault。

这个故事的精神是 - 每当您读取字节并将它们转换为字符串字符时，必须使用正确的字符集对字节进行解码，否则您将丢失数据。这在 Delphi 5 中是正确的（但没有严格执行），在 Delphi 2009+ 中更是如此。

使用 Indy 10 发送字节

如何解决使用 Indy 10 发送字节

解决方法

相关推荐