是否可以在xslt中嵌套动态节点集？

如何解决是否可以在xslt中嵌套动态节点集？

| 我想知道是否可以在XSLT中嵌套动态节点集，如果可以，如何使用xPath选择它们。这是一项更大任务的一部分。我只显示我卡住的部分。 这是我的XSLT：

<xsl:variable name=\"Tables\">
  <xsl:for-each select=\"Table\">
    <xsl:variable name=\"TableName\" select=\"Name | @Name\"/>
    <xsl:variable name=\"Columns\">
      <xsl:for-each select=\"Column\">
        <xsl:variable name=\"ColumnName\" select=\"Name | @Name\"/>
        <xsl:variable name=\"Type\" select=\"Type | @Type\"/>
        <Column>
          <Name>
            <xsl:value-of select=\"$ColumnName\"/>
          </Name>
          <Type>
            <xsl:value-of select=\"$Type\"/>
          </Type>
        </Column>
      </xsl:for-each>
    </xsl:variable>
    <Table>
      <Name>
        <xsl:value-of select=\"$TableName\"/>
      </Name>
      <Columns>
        <xsl:value-of select=\"$Columns\"/>
      </Columns>
    </Table>
  </xsl:for-each>
</xsl:variable>

<xsl:for-each select=\"msxsl:node-set($Tables)/Table\">
  Table Name: <xsl:value-of select=\"Name\"/>
  <xsl:for-each select=\"msxsl:node-set(Columns)/Column\" xml:space=\"preserve\">
    Column Name: <xsl:value-of select=\"Name\"/>
    Column Type: <xsl:value-of select=\"Type\"/>
  </xsl:for-each>
</xsl:for-each>

这是我的XML：

  <Table Name=\"Product\">
    <Column Name=\"ProductID\" Type=\"int\"/>
    <Column Name=\"Name\" Type=\"string\"/>
    <Column Name=\"Cost\" Type=\"decimal\"/>
    <Column Name=\"Area\" Type=\"decimal?\"/>
  </Table>
  <Table Name=\"Market\">
    <Column Name=\"MarketID\" Type=\"int\"/>
    <Column Name=\"Name\" Type=\"string\"/>
    <Column Name=\"MinimumASP\" Type=\"double\"/>
    <Column Name=\"MaximumASP\" Type=\"double\"/>
  </Table>

这是我当前得到的输出：

  Table Name: Product
  Table Name: Market

这就是我想要得到的：

  Table Name: Product
  Column Name: ProductID
  Column Type: int
  Column Name: Name
  Column Type: string
  Column Name: Cost
  Column Type: decimal
  Column Name: Area
  Column Type: decimal?
  Table Name: Market
  Column Name: MarketID
  Column Type: int
  Column Name: Name
  Column Type: string
  Column Name: MinimumASP
  Column Type: double
  Column Name: MaximumASP
  Column Type: double

    

解决方法

所需的结果可以通过一种更简单的方式产生，并且不需要创建任何临时树：

<xsl:stylesheet version=\"1.0\"
 xmlns:xsl=\"http://www.w3.org/1999/XSL/Transform\">
 <xsl:output method=\"text\"/>
 <xsl:strip-space elements=\"*\"/>

 <xsl:template match=\"*/*\">
  <xsl:apply-templates select=\"@*|*\"/>
 </xsl:template>

 <xsl:template match=\"@*\">
  <xsl:value-of select=
   \"concat(name(..),\' \',name(),\': \',.)\"/>
  <xsl:text>&#xA;</xsl:text>
 </xsl:template>
</xsl:stylesheet>

当对提供的XML文档应用此转换时（包装在单个top元素中以使其格式正确）：

<t>
    <Table Name=\"Product\">
        <Column Name=\"ProductID\" Type=\"int\"/>
        <Column Name=\"Name\" Type=\"string\"/>
        <Column Name=\"Cost\" Type=\"decimal\"/>
        <Column Name=\"Area\" Type=\"decimal?\"/>
    </Table>
    <Table Name=\"Market\">
        <Column Name=\"MarketID\" Type=\"int\"/>
        <Column Name=\"Name\" Type=\"string\"/>
        <Column Name=\"MinimumASP\" Type=\"double\"/>
        <Column Name=\"MaximumASP\" Type=\"double\"/>
    </Table>
</t>

所需的正确结果产生了：

Table Name: Product
Column Name: ProductID
Column Type: int
Column Name: Name
Column Type: string
Column Name: Cost
Column Type: decimal
Column Name: Area
Column Type: decimal?
Table Name: Market
Column Name: MarketID
Column Type: int
Column Name: Name
Column Type: string
Column Name: MinimumASP
Column Type: double
Column Name: MaximumASP
Column Type: double