为什么会出现此错误消息？：无效获取索引“game_started”基于：“节点”

如何解决为什么会出现此错误消息？：无效获取索引“game_started”基于：“节点”

你能帮我吗，我有这个脚本：

extends KinematicBody2D

var motion = Vector2(0,300)

var sensitivity = 13
onready var player = get_node("../Player")
onready var enemy = get_node("../Enemy")


func _ready():
    randomize()
    reset_ball()

func _physics_process(delta):
    if not get_parent().game_started:
        return
    if is_on_wall():
        motion.x *= -1
    
    
    if is_on_floor():
        touch_someone(player)
    if is_on_ceiling():
        touch_someone(enemy)
    
    move_and_slide(motion,Vector2(0,-1))


func touch_someone(node):
    motion.y *= -1
    motion.x = (position.x - node.position.x) * sensitivity

func reset_ball():
    motion.x = rand_range(-300,300)

nd 当我运行游戏时出现此错误消息无效的获取索引 'game_started'（基于：'Node'）。

This is the error

解决方法

错误告诉您在父节点中没有定义 game_started。有一个父节点，但它没有定义属性 game_started。

您可能打算将它作为一个属性，但是您忘记定义它，在其他地方定义了它，或者您确实在正确的位置定义了它，但是在错误的父节点下实例化了节点。 但是，也有可能你把它变成了一个方法，只是忘记了 ()。我不知道是哪种情况。

无论如何，在 Godot 中，一个常见的设计模式是向下访问场景树并向上发送信号。在这种情况下，您正在尝试访问场景树。这是有问题的，因为场景无法确定将在哪里实例化。

我会给你一些解决这个问题的方法：

检查 game_started 是否存在。

对您的架构影响较小的更改是在尝试读取之前检查父节点是否具有 game_started。看起来像这样：
```
var parent = get_parent
if !"game_started" in parent or !parent.game_started:
    return
```
但是请注意，即使这消除了错误，也不能解决问题的根源。由于 game_started 无论如何都没有在父级中定义。

此外，_physics_process 仍在被调用。有一些方法甚至可以不调用，这对性能更好。会回到那个。
让家长访问孩子。

您要完成的是根据 _physics_process 的值启用和禁用 game_started。有一种方法可以在引擎中启用和禁用 _physics_process：set_physics_process。

大概在某处有一些其他代码在父级上设置 game_started，在那一刻它可以调用子级上的 set_physics_process 以相应地禁用或启用 _physics_process。

您甚至可以使用属性（带有 setget）来达到此效果。

例如：
```
var game_started:bool setget set_game_started

func set_game_started(new_value:bool) -> void:
    if game_started == new_value:
        return

    for child in get_children():
        child.set_physics_process(new_value)

    game_started = new_value
```
这样，您的脚本就不必检查 game_started。一个缺点是代码仅在直接子代上使用 set_physics_process。我们可以写一个递归版本，但是，我们可以做得更好！
使用暂停。

正如您在 pausing games 中看到的，您可以使用 get_tree().paused 来获取或设置游戏是否暂停。哪个会根据 pause_mode 停止 _physics_process（以及其他方法）。

因此，您可以让父级更新 get_tree().paused...

假设您还想暂停一下，您可以遵循以下模式：
```
var game_started:bool setget set_game_started
var game_paused:bool setget set_game_paused

func set_game_started(new_value:bool) -> void:
    game_started = new_value
    update_pause()

func set_game_paused(new_value:bool) -> void:
    game_paused = new_value
    update_pause()

func update_pause() -> void:
    get_tree().paused = !game_started or game_paused
```
然后，对于在游戏暂停或未启动时仍应工作的节点，您可以设置 pause_mode = PAUSE_MODE_PROCESS 以免它们收到 _physics_process 等。禁用。然后他们可以检查game_started和game_paused以区分游戏是暂停还是未开始。

缺点是这会影响所有节点……如果只有 game_started 和 game_paused 可以在任何地方可用……好吧，我们也可以这样做！
使用自动加载。

使用具有 game_started 等的节点制作场景的 autoload（通过项目设置）。这样它就可以从任何地方获得。然后你可以从任何地方访问它。

如上所述，您可以结合 paused 执行此操作。这是我推荐的。

或者。因为你可以从任何地方访问它，你可以简单地访问它而不是父：
```
if !autoload_name.game_started:
    return
```
这是访问关闭和信号开启规则的例外。由于自动加载随处可用，并且不取决于场景的实例化位置或方式。

我提醒您，paused 和 set_physics_process 将避免调用 _physics_process，因此比这种检查方式更高效。 >

为什么会出现此错误消息？：无效获取索引“game_started”基于：“节点”

如何解决为什么会出现此错误消息？：无效获取索引“game_started”基于：“节点”

解决方法

相关推荐