排序算法

分类：VB作者：编程之家用户

为什么有这么多的排序算法?

首先，在计算机编程中排序是一个经常遇到的问题。数据只有经过排序后，才更有意义。其次，排序算法说明了许多重要的算法的技术，例如二进制细分，递归和线性添加。最后要说明的一点是不同的算法有不同的优缺点，没有一种算法在任何情况下都是最好的算法。

汽泡排序法

该算法是专门针对已部分排序的数据进行排序的一种排序算法。如果在你的数据清单中只有一两个数据是乱序的话，用这种算法就是最快的排序算法。如果你的数据清单中的数据是随机排列的，那么这种方法就成了最慢的算法了。因此在使用这种算法之前一定要慎重。

这种算法的核心思想是扫描数据清单，寻找出现乱序的两个相邻的项目。当找到这两个项目后，交换项目的位置然后继续扫描。重复上面的操作直到所有的项目都按顺序排好。

图1是对这种算法的说明。在该例中，数字1的未按顺序排好。第一次扫描清单时，程序找到4和1是两个相邻的乱序项目，于是交换它们的位置。以此类推，直到将所有的项目按1234排好。数字1就象上升的汽泡一样，这就是这一算法名称的由来。

2 2 2 1
3 3 1 2
4 1 3 3
1 4 4 4
图1.

你可以改进该算法，让程序自下而上开始扫描，这样只须一次就能排好顺序了。

下面是用VB代码实现这一算法的例子： 

' min and max are the minimum and maximum indexes
' of the items that might still be out of order.
Sub BubbleSort (List() As Long,ByVal min As Integer,_
    ByVal max As Integer)
Dim last_swap As Integer
Dim i As Integer
Dim j As Integer
Dim tmp As Long

    ' Repeat until we are done.
    Do While min < max
        ' Bubble up.
        last_swap = min - 1
        ' For i = min + 1 To max
        i = min + 1
        Do While i <= max
            ' Find a bubble.
            If List(i - 1) > List(i) Then
                ' See where to drop the bubble.
                tmp = List(i - 1)
                j = i
                Do
                    List(j - 1) = List(j)
                    j = j + 1
                    If j > max Then Exit Do
                Loop While List(j) < tmp
                List(j - 1) = tmp
                last_swap = j - 1
                i = j + 1
            Else
                i = i + 1
            End If
        Loop
        ' Update max.
        max = last_swap - 1

        ' Bubble down.
        last_swap = max + 1
        ' For i = max - 1 To min Step -1
        i = max - 1
        Do While i >= min
            ' Find a bubble.
            If List(i + 1) < List(i) Then
                ' See where to drop the bubble.
                tmp = List(i + 1)
                j = i
                Do
                    List(j + 1) = List(j)
                    j = j - 1
                    If j < min Then Exit Do
                Loop While List(j) > tmp
                List(j + 1) = tmp
                last_swap = j + 1
                i = j - 1
            Else
                i = i - 1
            End If
        Loop
        ' Update min.
        min = last_swap + 1
    Loop
End Sub

选择排序法 选择排序法是一个很简单的算法。其原理是首先找到数据清单中的最小的数据，然后将这个数据同第一个数据交换位置；接下来找第二小的数据，再将其同第二个数据交换位置，以此类推。下面是VB代码实现该算法。 

Sub Selectionsort (List() As Long,min As Integer,_
    max As Integer)
Dim i As Integer
Dim j As Integer
Dim best_value As Long
Dim best_j As Integer

    For i = min To max - 1
        best_value = List(i)
        best_j = i
        For j = i + 1 To max
            If List(j) < best_value Then
                best_value = List(j)
                best_j = j
            End If
        Next j
        List(best_j) = List(i)
        List(i) = best_value
    Next i
End Sub

当寻找第I小的数据时，你必须检查N-I个项目，所以这一算法所用的步骤可用下面这个公式求得。 

    N + (N - 1) + (N - 2) + ... + 1 = N * (N + 1) / 2

选择排序法适用于较少数据的排序。此外由于算法较简单，因此他的代码也比较简单，这就为我们维护代码带来了方便。实际上如果你的数据相当少的话，这种算法的速度快过其它更复杂的算法。

快速排序法

快速排序法对于大量数据的排序特别有用。其基本原理是：首先检查数据列表中的数据数，如果小于两个，则直接退出程序。如果有超过两个以上的数据，就选择一个分割点将数据分成两个部分，小于分割点的数据放在一组，其余的放在另一组，然后分别对两组数据排序。

通常分割点的数据是随机选取的。这样无论你的数据是否已被排列过，你所分割成的两个字列表的大小是差不多的。而只要两个子列表的大小差不多，该算法所需的步骤就是N * log(N) 步。对于使用比较法进行排序的算法来讲这是最快的方法。下面是用VB代码实现这一算法的例子。 

Sub Quicksort (List() As Long,max As Integer)
Dim med_value As Long
Dim hi As Integer
Dim lo As Integer
Dim i As Integer

    ' If the list has no more than 1 element,it's sorted.
    If min >= max Then Exit Sub

    ' Pick a dividing item.
    i = Int((max - min + 1) * Rnd + min)
    med_value = List(i)

    ' Swap it to the front so we can find it easily.
    List(i) = List(min)

    ' Move the items smaller than this into the left
    ' half of the list. Move the others into the right.
    lo = min
    hi = max
    Do
        ' Look down from hi for a value < med_value.
        Do While List(hi) >= med_value
            hi = hi - 1
            If hi <= lo Then Exit Do
        Loop
        If hi <= lo Then
            List(lo) = med_value
            Exit Do
        End If

        ' Swap the lo and hi values.
        List(lo) = List(hi)
        
        ' Look up from lo for a value >= med_value.
        lo = lo + 1
        Do While List(lo) < med_value
            lo = lo + 1
            If lo >= hi Then Exit Do
        Loop
        If lo >= hi Then
            lo = hi
            List(hi) = med_value
            Exit Do
        End If

        ' Swap the lo and hi values.
        List(hi) = List(lo)
    Loop

    ' Sort the two sublists
    Quicksort List(),min,lo - 1
    Quicksort List(),lo + 1,max
End Sub

计数排序法

前面提到过，对于使用比较法作为算法基础的算法来说，最快需N * log(N)步才能完成排序。计数排序法不作用比较，所以它不受此限制。实际上该算法是如此之快，以致于你会认为是使用了魔术，而不是数学运算来排序。

另一方面，计数排序法只能用于特殊的情况。首先，所有的要进行排序的数据必须是整数，不能对字符使用该算法；其次，数据的范围有限，如果你的数据是在1到1000之内，用这种算法的效果就非常好，但如果你的数据是在1到30000之间，该算法就根本不能用。

首先该算法创建一个整数类型的临时数组，该数组的上下标分别是要排序的数据的最大最小值。如果数据列表的最大最小值从min_item到max_item,该算法就将数组创建成下面这样： 

    Dim Counts() As Integer

    ReDim Counts(min_item To max_item)
接下来，算法检查列表中的每一个项目，并增加对应该项目的数组元素的值，当这一阶段完成后，Counts(I)的数值就是就是数值为I的基础上的个数。 
    For I = min To Max
        Counts(List(I)) = Counts(List(I)) + 1
    Next I
程序扫描Counts数组，将counts转换成被排序列表中的偏移量。 
    next_spot = 1
    For i = min_value To max_value
        this_count = counts(i)
        counts(i) = next_spot
        next_spot = next_spot + this_count
    Next i
最后将数据进行排序

下面是实现该算法的VB代码 

Sub Countingsort (List() As Long,sorted_list() As Long,_
    min As Integer,max As Integer,min_value As Long,_
    max_value As Long)
Dim counts() As Integer
Dim i As Integer
Dim this_count As Integer
Dim next_offset As Integer

    ' Create the Counts array.
    ReDim counts(min_value To max_value)

    ' Count the items.
    For i = min To max
        counts(List(i)) = counts(List(i)) + 1
    Next i

    ' Convert the counts into offsets.
    next_offset = min
    For i = min_value To max_value
        this_count = counts(i)
        counts(i) = next_offset
        next_offset = next_offset + this_count
    Next i

    ' Place the items in the sorted array.
    For i = min To max
        sorted_list(counts(List(i))) = List(i)
        counts(List(i)) = counts(List(i)) + 1
    Next i
End Sub

总结

下表是各种算法的优缺点比较，正如你所见到的那样，每种算法只是在某一情况下表现得最好，下面是选择算法时的一些原则：

  • 如果你的数据列表中有99%数据已排过序，则用汽泡排序法。
  • 如果你要排序的数据较少(100个以下)，则用选择排序法。
  • 如果你的数据都是整数，并且数值不大(几千以内)，则用计数排序法。
  • 否则的话用快速排序法法
算法 优点 缺点
汽泡排序法 对以初步排序的数据来说这种方法的速度很快 在其它情况下运行速度较慢
选择排序法 非常简单 对大量数据的排序速度很慢
容易明白
对于少量数据的排序来说速度很快
快速排序法 对大量数据的排序来说速度很快 如果有大量重复的数据就比较麻烦
计数排序法 当数据数值较小(1-1000之间)时，速度非常快 当数据数值较大时，速度较慢
需额外的内存
只能对整数类型的数据排序

版权声明：本文内容由互联网用户自发贡献，该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容， 请发送邮件至 dio@foxmail.com 举报，一经查实，本站将立刻删除。

相关推荐

VB Format函数
Format[$] ( expr [ , fmt ] ) format 返回变体型 format$ 强制返回为文本 -------------------------------- 数字类型的格式化 --------------------------------     固定格式参数：     General Number 普通数字，如可以用来去掉千位分隔号     format$("100,1
vb6/ASP FORMAT MM/DD/YYYY
VB6或者ASP 格式化时间为 MM/dd/yyyy 格式，竟然没有好的办法， Format 或者FormatDateTime 竟然结果和系统设置的区域语言的日期和时间格式相关。意思是尽管你用诸如 Format(Now, "MM/dd/yyyy")，如果系统的设置格式区域语言的日期和时间格式分隔符是"-",那他还会显示为 MM-dd-yyyy     只有拼凑： <%response.write
VB.net 捕获项目全局异常
在项目中添加如下代码：新建窗口来显示异常信息。 Namespace My ‘全局错误处理，新的解决方案直接添加本ApplicationEvents.vb 到工程即可 ‘添加后还需要一个From用来显示错误。如果到这步还不会则需要先打好基础啦 ‘======================================================== ‘以下事件
实现用VB.Net/(C#)开发K/3 BOS 插件的真正可行方法
转了这一篇文章，原来一直想用C#做k3的插件开发，vb没有C#用的爽呀，这篇文章写与2011年，看来我以前没有认真去找这个方法呀。 https://blog.csdn.net/chzjxgd/article/details/6176325 金蝶K3 BOS的插件官方是用VB6编写的，如果  能用.Net下的语言工具开发BOS插件是一件很愉快的事情，其中缘由不言而喻，而本文则是个人首创，实现在了用V
vb，wps，excel 分裂
Sub 分列() ‘以空格为分隔符，连续空格只算1个。对所选中的单元格进行处理 Dim m As Range, tmpStr As String, s As String Dim x As Integer, y As Integer, subStr As String If MsgBox("确定要分列处理吗？请确定分列的数据会覆盖它后面的单元格！", _
VB文件 hash 查看器
  窗体代码 1 Private Sub Text1_OLEDragDrop(Data As DataObject, Effect As Long, Button As Integer, Shift As Integer, X As Single, Y As Single) 2 Dim path As String, hash As String 3 For Each fil
VB.NET MYSQL DataGridView 增删改查INSERT,SELECT,UPDATE,DELETE
  Imports MySql.Data.MySqlClient Public Class Form1 ‘ GLOBAL DECLARATIONS Dim conString As String = "Server=localhost;Database=net2;Uid=root;Pwd=123456;" Dim con As New MySqlConnection
VB.NET 使用ADODB連接資料庫滙出到EXCEL
‘導入命名空間 Imports ADODB Imports Microsoft.Office.Interop   Private Sub A1() Dim Sql As String Dim Cnn As New ADODB.Connection Dim Rs As New ADODB.Recordset Dim S As String   S = "Provider=OraOLEDB.Oracl
vb.net 多线程運用 ping
Imports System.IO Imports System.Threading Imports System.Diagnostics Public Class Form1 Dim A(254) As String    Function ping(ByVal IP As Integer) As String Dim IPAddress As String IPAddress = "10.0.
VB等待进程结束
VB运行EXE程序，并等待其运行结束 参考：https://blog.csdn.net/useway/article/details/5494084 Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long Pr
vb中去掉string数组的一部分
今天碰到一个问题，登陆的时候，如果不需要验证手机号为空，则不去验证手机号 因为登陆的时候所有的验证信息都存放在一个数组里 Dim CheckUserInfo() As String ={UserBirthday, SecEmail, UserMob, UserSex, RealNameFirst, RealName, CheckCardID, CheckCardType, Contactemail
VB如何连接SQL Server数据库
在VB6.0中，数据访问接口有三种： 1、ActiveX数据对象（ADO） 2、远程数据对象（RDO） 3、数据访问对象（DAO） 1.使用ADO（ActiveX Data Objec，ActiveX数据对象）连接SQL Server 1）使用ADO控件连接 使用ADO控件的ConnectionString属性就可以连接SQL Server，该属性包含一个由分号分隔的argument=value语
Visual Basic 6.0VB6.0详细安装过程
注：大家如果没有VB6.0的安装文件，可自行百度一下下载，一般文件大小在200M左右的均为完整版的软件，可以使用。   特别提示：安装此软件的时候最好退出360杀毒软件（包括360安全卫士，电脑管家等，如果电脑上有这些软件的话），因为现如今的360杀毒软件直接会对VB6.0软件误报，这样的话就可能会在安装过程中被误报阻止而导致安装失败，或者是安装后缺乏很多必须的组件（其它的杀毒软件或安全卫士之类的
使用VB6读取数据库资源并发送邮件原创
Private Sub Form_Load() Call conndb End Sub Private Function conndb() Dim cn As New ADODB.Connection Dim rs As New ADODB.Recordset Dim strCn, sql As String Dim db_host As String Dim db_user As String
POS VB
  PPSM06S70:  Add  moddate  EDITSPRINTJOB:  MAX(TO_CHAR(ETRN.MODDATE, ‘yyyy/mm/dd/HH24:MI AM‘)) ACTUAL_SHIPDATE   4.Test Scenario (1) ：Query SQL Test DN:8016578337 SELECT CTRN.TKCTID TRUCK_ID,        
vb.net 水晶報表CrystalReport 動態設定資料庫來源
  沒有出現CrystalReportViewer時,須安裝CRforVS_13_0. 新增1個數據集,新增1個數據表,添加二列,列名要和資料庫名一樣. 修改目標Framework 修改app.config, <startup >改成<startup useLegacyV2RuntimeActivationPolicy ="true">  CrystalReport1.rpt增加數據庫專家 在表單
VB.net 与线程
Imports System.Threading Imports System Public Class Form1 Dim th1, th2 As Thread Public Sub Method1() Dim i As Integer For i = 1 To 100 If Me.Label1.BackColor =
vb.net Process32First和Module32First
Friend Const PROCESS_ALL_ACCESS = &H1F0FFF = 2035711 Friend Const PROCESS_VM_READ = &H10 Friend Const PROCESS_VM_WRITE = &H20 Friend Const PAGE_READONLY = &H2 Friend Const PAGE_READWRITE = &H4 Friend
vb.net 分割byte数组的方法SplitBytes
以下代码随手写的 并没有大量测试 效率也有待提升 如果需要C#的请自行转换 Function SplitBytes(Data As Byte(), Delimiter As Byte()) As List(Of Byte()) Dim i = 0 Dim List As New List(Of Byte()) Dim bytes As New
VB.NET连接SQL_Server实例
Imports System.Data.SqlClient Public Class Form1 REM Public conn1 As SqlConnection = New SqlConnection("server=.; Integrated Security=False;Initial Catalog= mydatabase1; User ID= sa;password")
pythonJavaScriptjavaHTMLPHPreactjsC#AndroidCSSNode.jssqlrpython-3.xMysqLjQueryc++pandasFlutterangularIOSdjangolinuxswifttypescript路由器JSON路由器设置无线路由器h3c华三华三路由器设置华三路由器电脑软件教程arraysdocker软件图文教程Cvue.jslaravelspring-boot